configure.ac

   1 # configure.ac with sensible comments
   2
   3 ### INITIALIZATION ############################################################
   4
   5 # Initialize Autoconf
   6 # Args: (human-readable package name, package version, bug report address,
   7 # tarballname)
   8 AC_INIT([chimara], [0.9])
   9 # Sanity check to make sure we are running Autoconf from the right directory
  10 AC_CONFIG_SRCDIR(libchimara/chimara-glk.c)
  11 # Put m4 macros in their own directory
  12 AC_CONFIG_MACRO_DIR(m4)
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([-Wall])
  15 # Configure with --enable-silent-rules to cut down on clutter
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 ### LIBRARY VERSIONING ########################################################
  19 # Only update immediately before a public release
  20
  21 CHIMARA_CURRENT=0  # Increment if interface changes
  22 CHIMARA_REVISION=0 # Increment if source changes; set 0 if interface changes
  23 CHIMARA_AGE=0 # Increment if interfaces added; set 0 if removed
  24 LT_VERSION_INFO="$CHIMARA_CURRENT:$CHIMARA_REVISION:$CHIMARA_AGE"
  25 AC_SUBST(LT_VERSION_INFO)
  26
  27 ### REQUIREMENTS ##############################################################
  28 # Recommended GTK version: at least 2.12
  29 # Recommended Glib version: at least 2.16
  30 GTK_REQUIRED_VERSION=2.6
  31 GLIB_REQUIRED_VERSION=2.6
  32 GTK_DOC_REQUIRED_VERSION=1.9
  33 AC_SUBST(GTK_REQUIRED_VERSION)
  34 AC_SUBST(GLIB_REQUIRED_VERSION)
  35 AC_SUBST(GTK_DOC_REQUIRED_VERSION)
  36
  37 ### DECLARE COMPILERS #########################################################
  38
  39 AC_USE_SYSTEM_EXTENSIONS     # Define _GNU_SOURCE if using GCC
  40 AC_PROG_CC                   # C compiler
  41 AM_PROG_CC_C_O               # Automake requires this for per-target CFLAGS
  42 AC_C_INLINE                  # Define inline keyword
  43 AC_PROG_YACC                 # Building nitfol requires yacc
  44
  45 ### DECLARE PROGRAMS ##########################################################
  46
  47 AC_PROG_INSTALL              # Install
  48 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:]) # Disable unnecessary Libtool checks
  49 m4_defun([_LT_AC_LANG_F77_CONFIG], [:]) # to save time (1.5 only)
  50 LT_INIT                      # Libtool 2.2.6 and up
  51 #LT_INIT([dlopen])           # Should call it this way, but
  52 #LT_PREREQ([2.2.6])          # ...goddamn Debian still has 1.5
  53 AC_PROG_LIBTOOL              # Old way of declaring Libtool
  54 AM_GNU_GETTEXT([external])   # Gettext, link to system libintl
  55 IT_PROG_INTLTOOL([0.40.0])   # Intltool
  56 PKG_PROG_PKG_CONFIG          # pkg_config
  57 GTK_DOC_CHECK($GTK_DOC_REQUIRED_VERSION)
  58 # Other utilities used in this package's various make scripts
  59 AC_PROG_AWK
  60 AC_PATH_PROG([PERL], [perl]) # Perl
  61 AC_PATH_PROG([TEST], [test]) # Test
  62 AC_PATH_PROG([ECHO], [echo]) # Echo
  63
  64 ### TYPES #####################################################################
  65
  66 AC_TYPE_UINT8_T
  67 AC_TYPE_UINT16_T
  68 AC_TYPE_INT32_T
  69 AC_TYPE_UINT32_T
  70
  71 ### INTERNATIONALIZATION ######################################################
  72
  73 AM_GNU_GETTEXT_VERSION([0.17])
  74 GETTEXT_PACKAGE=chimara
  75 AC_SUBST(GETTEXT_PACKAGE)
  76 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
  77
  78 ### ILIAD #####################################################################
  79 AC_ARG_ENABLE([iliad],
  80         [AS_HELP_STRING([--enable-iliad=@<:@yes/no@:>@],
  81                 [Compiles Chimara for the iLiad @<:@default=no@:>@])],
  82         [],
  83         [enable_iliad=no])
  84 AM_CONDITIONAL(TARGET_ILIAD, $TEST "x$enable_iliad" = xyes)
  85
  86 ### BUILD WITHOUT RECENT FILES MANAGER #########################################
  87 # (to work around a bug on OS X)
  88 AC_ARG_ENABLE([recent],
  89         [AS_HELP_STRING([--disable-recent],
  90                 [Omit recent files menu (to work around a bug on OS X])],
  91         [],
  92         [enable_recent=yes])
  93 AS_IF([$TEST "x$enable_recent" = "xyes"],
  94         [OPEN_RECENT_MENU_ITEM="<menuitem action=\"recent\"/>"],
  95         [OPEN_RECENT_MENU_ITEM="<!--  <menuitem action=\"recent\"/>-->"])
  96 AC_SUBST(OPEN_RECENT_MENU_ITEM)
  97
  98 ### RPM CONFIGURATION ##########################################################
  99 # --enable-rpm requires rpm and rpmbuild
 100 AC_PATH_PROG([RPMBUILD], [rpmbuild], [notfound])
 101 AC_ARG_ENABLE([rpm],
 102         [AS_HELP_STRING([--enable-rpm=@<:@yes/no@:>@],
 103                 [Configure for building RPM package @<:@default=no@:>@ (requires rpm and rpmbuild)])],
 104         [AS_IF([$TEST "x$enable_rpm" = xyes],
 105                 [AS_IF([$TEST "x$RPMBUILD" = xnotfound],
 106                         [AC_MSG_ERROR([rpmbuild is required for --enable-rpm])])])],
 107         [enable_rpm=no])
 108 AM_CONDITIONAL(BUILDING_RPM, $TEST "x$enable_rpm" = xyes)
 109
 110 ### SOUND LIBRARY TO USE ######################################################
 111
 112 AC_ARG_WITH([gstreamer],
 113         [AS_HELP_STRING([--without-gstreamer], [Disable GStreamer sound])],
 114         [],
 115         [with_gstreamer=yes])
 116 SOUND_MODULE=
 117 AS_IF([$TEST "x$with_gstreamer" != xno],
 118         [AC_DEFINE([GSTREAMER_SOUND], [1], [Define to enable sound support with GStreamer])
 119         SOUND_MODULE="gstreamer-0.10 >= 0.10.12"])
 120
 121 ### CHECK FOR LIBRARIES #######################################################
 122
 123 # Libraries needed to build Chimara library
 124 PKG_CHECK_MODULES([CHIMARA], [
 125         glib-2.0 >= $GLIB_REQUIRED_VERSION
 126         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 127         gthread-2.0
 128         gmodule-2.0
 129         pango
 130         $SOUND_MODULE
 131 ])
 132 CHIMARA_LIBS="$CHIMARA_LIBS -lm"
 133 AC_SUBST(CHIMARA_LIBS)
 134 # Libraries needed to build test programs
 135 PKG_CHECK_MODULES([TEST], [
 136         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 137         gmodule-2.0 >= $GLIB_REQUIRED_VERSION
 138 ])
 139
 140 # GStreamer plugins needed to run library
 141 AS_IF([$TEST "x$with_gstreamer" != xno], [
 142         m4_defun([AX_GST_REQUIRE_ELEMENT],
 143                 [AM_GST_ELEMENT_CHECK([$1],
 144                         [],
 145                         [AC_MSG_ERROR([GStreamer element $1 not found. You need to install gstreamer-plugins-m4_default([$2], [base]).])]
 146                 )]
 147         )
 148         AX_GST_REQUIRE_ELEMENT([giostreamsrc])
 149         AX_GST_REQUIRE_ELEMENT([typefind])
 150         AX_GST_REQUIRE_ELEMENT([audioconvert])
 151         AX_GST_REQUIRE_ELEMENT([volume])
 152         AX_GST_REQUIRE_ELEMENT([oggdemux])
 153         AX_GST_REQUIRE_ELEMENT([vorbisdec])
 154         AX_GST_REQUIRE_ELEMENT([autoaudiosink], [good])
 155         AX_GST_REQUIRE_ELEMENT([aiffparse], [bad])
 156         AX_GST_REQUIRE_ELEMENT([modplug], [bad])
 157 ])
 158
 159 # Plugin flags; include '-module' in each Makefile.am, because AC_SUBSTed
 160 # variables are black boxes to Automake, so it has to know about it being a
 161 # module in the makefile itself.
 162 PLUGIN_LIBTOOL_FLAGS='-avoid-version -shared -export-symbols-regex "^glk"'
 163 AC_SUBST(PLUGIN_LIBTOOL_FLAGS)
 164
 165 ### OUTPUT ####################################################################
 166
 167 # Output platform-specific definitions to config.h
 168 AC_CONFIG_HEADERS([config.h])
 169 # List of other files for Autoconf to output
 170 AC_CONFIG_FILES([
 171 Makefile
 172 chimara.pc
 173 chimara-plugin.pc
 174 chimara.spec
 175 libchimara/Makefile
 176 interpreters/Makefile
 177 interpreters/frotz/Makefile
 178 interpreters/nitfol/Makefile
 179 interpreters/glulxe/Makefile
 180 interpreters/git/Makefile
 181 tests/Makefile
 182 player/Makefile
 183 player/chimara.menus
 184 docs/Makefile
 185 docs/reference/Makefile
 186 docs/reference/version.xml
 187 docs/reference/build-selector-table.pl
 188 po/Makefile.in
 189 ])
 190
 191 # Do it
 192 AC_OUTPUT
 193