configure.ac

   1 # configure.ac with sensible comments
   2
   3 ### INITIALIZATION ############################################################
   4
   5 # Initialize Autoconf
   6 # Args: (human-readable package name, package version, bug report address,
   7 # tarballname)
   8 AC_INIT([chimara], [0.9])
   9 # Sanity check to make sure we are running Autoconf from the right directory
  10 AC_CONFIG_SRCDIR(libchimara/chimara-glk.c)
  11 # Put m4 macros in their own directory
  12 AC_CONFIG_MACRO_DIR(m4)
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([-Wall])
  15 # Configure with --enable-silent-rules to cut down on clutter
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 ### LIBRARY VERSIONING ########################################################
  19 # Only update immediately before a public release
  20
  21 CHIMARA_CURRENT=0  # Increment if interface changes
  22 CHIMARA_REVISION=0 # Increment if source changes; set 0 if interface changes
  23 CHIMARA_AGE=0 # Increment if interfaces added; set 0 if removed
  24 LT_VERSION_INFO="$CHIMARA_CURRENT:$CHIMARA_REVISION:$CHIMARA_AGE"
  25 AC_SUBST(LT_VERSION_INFO)
  26
  27 ### REQUIREMENTS ##############################################################
  28 # Recommended GTK version: at least 2.12
  29 # Recommended Glib version: at least 2.16
  30 GTK_REQUIRED_VERSION=2.6
  31 GLIB_REQUIRED_VERSION=2.6
  32 GTK_DOC_REQUIRED_VERSION=1.9
  33 AC_SUBST(GTK_REQUIRED_VERSION)
  34 AC_SUBST(GLIB_REQUIRED_VERSION)
  35 AC_SUBST(GTK_DOC_REQUIRED_VERSION)
  36
  37 ### DECLARE COMPILERS #########################################################
  38
  39 AC_USE_SYSTEM_EXTENSIONS     # Define _GNU_SOURCE if using GCC
  40 AC_PROG_CC                   # C compiler
  41 AM_PROG_CC_C_O               # Automake requires this for per-target CFLAGS
  42 AC_C_INLINE                  # Define inline keyword
  43 AC_PROG_YACC                 # Building nitfol requires yacc
  44
  45 ### DECLARE PROGRAMS ##########################################################
  46
  47 AC_PROG_INSTALL              # Install
  48 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:]) # Disable unnecessary Libtool checks
  49 m4_defun([_LT_AC_LANG_F77_CONFIG], [:]) # to save time (1.5 only)
  50 LT_INIT                      # Libtool 2.2.6 and up
  51 #LT_INIT([dlopen])           # Should call it this way, but
  52 #LT_PREREQ([2.2.6])          # ...goddamn Debian still has 1.5
  53 AC_PROG_LIBTOOL              # Old way of declaring Libtool
  54 AM_GNU_GETTEXT([external])   # Gettext, link to system libintl
  55 IT_PROG_INTLTOOL([0.40.0])   # Intltool
  56 PKG_PROG_PKG_CONFIG          # pkg_config
  57 GTK_DOC_CHECK($GTK_DOC_REQUIRED_VERSION)
  58 GLIB_GSETTINGS               # GSettings
  59 # Other utilities used in this package's various make scripts
  60 AC_PROG_AWK
  61 AC_PATH_PROG([PERL], [perl]) # Perl
  62 AC_PATH_PROG([TEST], [test]) # Test
  63 AC_PATH_PROG([ECHO], [echo]) # Echo
  64
  65 ### TYPES #####################################################################
  66
  67 AC_TYPE_UINT8_T
  68 AC_TYPE_UINT16_T
  69 AC_TYPE_INT32_T
  70 AC_TYPE_UINT32_T
  71
  72 ### INTERNATIONALIZATION ######################################################
  73
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 GETTEXT_PACKAGE=chimara
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
  78
  79 ### ILIAD #####################################################################
  80 AC_ARG_ENABLE([iliad],
  81         [AS_HELP_STRING([--enable-iliad=@<:@yes/no@:>@],
  82                 [Compiles Chimara for the iLiad @<:@default=no@:>@])],
  83         [],
  84         [enable_iliad=no])
  85 AM_CONDITIONAL(TARGET_ILIAD, $TEST "x$enable_iliad" = xyes)
  86
  87 ### BUILD WITHOUT RECENT FILES MANAGER #########################################
  88 # (to work around a bug on OS X)
  89 AC_ARG_ENABLE([recent],
  90         [AS_HELP_STRING([--disable-recent],
  91                 [Omit recent files menu (to work around a bug on OS X])],
  92         [],
  93         [enable_recent=yes])
  94 AS_IF([$TEST "x$enable_recent" = "xyes"],
  95         [OPEN_RECENT_MENU_ITEM="<menuitem action=\"recent\"/>"],
  96         [OPEN_RECENT_MENU_ITEM="<!--  <menuitem action=\"recent\"/>-->"])
  97 AC_SUBST(OPEN_RECENT_MENU_ITEM)
  98
  99 ### RPM CONFIGURATION ##########################################################
 100 # --enable-rpm requires rpm and rpmbuild
 101 AC_PATH_PROG([RPMBUILD], [rpmbuild], [notfound])
 102 AC_ARG_ENABLE([rpm],
 103         [AS_HELP_STRING([--enable-rpm=@<:@yes/no@:>@],
 104                 [Configure for building RPM package @<:@default=no@:>@ (requires rpm and rpmbuild)])],
 105         [AS_IF([$TEST "x$enable_rpm" = xyes],
 106                 [AS_IF([$TEST "x$RPMBUILD" = xnotfound],
 107                         [AC_MSG_ERROR([rpmbuild is required for --enable-rpm])])])],
 108         [enable_rpm=no])
 109 AM_CONDITIONAL(BUILDING_RPM, $TEST "x$enable_rpm" = xyes)
 110
 111 ### SOUND LIBRARY TO USE ######################################################
 112
 113 AC_ARG_WITH([gstreamer],
 114         [AS_HELP_STRING([--without-gstreamer], [Disable GStreamer sound])],
 115         [],
 116         [with_gstreamer=yes])
 117 SOUND_MODULE=
 118 AS_IF([$TEST "x$with_gstreamer" != xno],
 119         [AC_DEFINE([GSTREAMER_SOUND], [1], [Define to enable sound support with GStreamer])
 120         SOUND_MODULE="gstreamer-0.10 >= 0.10.12"])
 121
 122 ### CHECK FOR LIBRARIES #######################################################
 123
 124 # Libraries needed to build Chimara library
 125 PKG_CHECK_MODULES([CHIMARA], [
 126         glib-2.0 >= $GLIB_REQUIRED_VERSION
 127         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 128         gthread-2.0
 129         gmodule-2.0
 130         pango
 131         $SOUND_MODULE
 132 ])
 133 CHIMARA_LIBS="$CHIMARA_LIBS -lm"
 134 AC_SUBST(CHIMARA_LIBS)
 135 # Libraries needed to build test programs
 136 PKG_CHECK_MODULES([TEST], [
 137         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 138         gmodule-2.0 >= $GLIB_REQUIRED_VERSION
 139 ])
 140
 141 # GStreamer plugins needed to run library
 142 AS_IF([$TEST "x$with_gstreamer" != xno], [
 143         m4_defun([AX_GST_REQUIRE_ELEMENT],
 144                 [AM_GST_ELEMENT_CHECK([$1],
 145                         [],
 146                         [AC_MSG_ERROR([GStreamer element $1 not found. You need to install gstreamer-plugins-m4_default([$2], [base]).])]
 147                 )]
 148         )
 149         AX_GST_REQUIRE_ELEMENT([giostreamsrc])
 150         AX_GST_REQUIRE_ELEMENT([typefind])
 151         AX_GST_REQUIRE_ELEMENT([audioconvert])
 152         AX_GST_REQUIRE_ELEMENT([volume])
 153         AX_GST_REQUIRE_ELEMENT([oggdemux])
 154         AX_GST_REQUIRE_ELEMENT([vorbisdec])
 155         AX_GST_REQUIRE_ELEMENT([autoaudiosink], [good])
 156         AX_GST_REQUIRE_ELEMENT([aiffparse], [bad])
 157         AX_GST_REQUIRE_ELEMENT([modplug], [bad])
 158 ])
 159
 160 # Plugin flags; include '-module' in each Makefile.am, because AC_SUBSTed
 161 # variables are black boxes to Automake, so it has to know about it being a
 162 # module in the makefile itself.
 163 PLUGIN_LIBTOOL_FLAGS='-avoid-version -shared -export-symbols-regex "^glk"'
 164 AC_SUBST(PLUGIN_LIBTOOL_FLAGS)
 165
 166 ### OUTPUT ####################################################################
 167
 168 # Output platform-specific definitions to config.h
 169 AC_CONFIG_HEADERS([config.h])
 170 # List of other files for Autoconf to output
 171 AC_CONFIG_FILES([
 172 Makefile
 173 chimara.pc
 174 chimara-plugin.pc
 175 chimara.spec
 176 libchimara/Makefile
 177 interpreters/Makefile
 178 interpreters/frotz/Makefile
 179 interpreters/nitfol/Makefile
 180 interpreters/glulxe/Makefile
 181 interpreters/git/Makefile
 182 tests/Makefile
 183 player/Makefile
 184 player/chimara.menus
 185 docs/Makefile
 186 docs/reference/Makefile
 187 docs/reference/version.xml
 188 docs/reference/build-selector-table.pl
 189 po/Makefile.in
 190 ])
 191
 192 # Do it
 193 AC_OUTPUT
 194