configure.ac

   1 # configure.ac with sensible comments
   2
   3 ### INITIALIZATION ############################################################
   4
   5 # Initialize Autoconf
   6 # Args: (human-readable package name, package version, bug report address,
   7 # tarballname)
   8 AC_INIT([chimara], [0.1])
   9 # Sanity check to make sure we are running Autoconf from the right directory
  10 AC_CONFIG_SRCDIR(libchimara/chimara-glk.c)
  11 # Put m4 macros in their own directory
  12 AC_CONFIG_MACRO_DIR(m4)
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([-Wall])
  15 # Configure with --enable-silent-rules to cut down on clutter
  16 AM_SILENT_RULES
  17
  18 ### LIBRARY VERSIONING ########################################################
  19 # Only update immediately before a public release
  20
  21 CHIMARA_CURRENT=0  # Increment if interface changes
  22 CHIMARA_REVISION=0 # Increment if source changes; set 0 if interface changes
  23 CHIMARA_AGE=0 # Increment if interfaces added; set 0 if removed
  24 LT_VERSION_INFO="$CHIMARA_CURRENT:$CHIMARA_REVISION:$CHIMARA_AGE"
  25 AC_SUBST(LT_VERSION_INFO)
  26
  27 ### DECLARE COMPILERS #########################################################
  28
  29 AC_PROG_CC                   # C compiler
  30 AC_USE_SYSTEM_EXTENSIONS     # Define _GNU_SOURCE if using GCC
  31 AM_PROG_CC_C_O               # Automake requires this for per-target CFLAGS
  32 AC_C_INLINE                  # Define inline keyword
  33 AC_PROG_YACC                 # Building nitfol requires yacc
  34
  35 ### DECLARE PROGRAMS ##########################################################
  36
  37 AC_PROG_INSTALL              # Install
  38 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:]) # Disable unnecessary Libtool checks
  39 m4_defun([_LT_AC_LANG_F77_CONFIG], [:]) # to save time (1.5 only)
  40 LT_INIT                      # Libtool 2.2.6 and up
  41 #LT_INIT([dlopen])           # Should call it this way, but
  42 #LT_PREREQ([2.2.6])          # ...goddamn Debian still has 1.5
  43 AC_PROG_LIBTOOL              # Old way of declaring Libtool
  44 AM_GNU_GETTEXT([external])   # Gettext, link to system libintl
  45 IT_PROG_INTLTOOL([0.35.0])   # Intltool
  46 PKG_PROG_PKG_CONFIG          # pkg_config
  47 GTK_DOC_CHECK(1.9)           # Gtk-Doc
  48 # Other utilities used in this package's various make scripts
  49 AC_PROG_AWK
  50 AC_PATH_PROG([PERL], [perl]) # Perl
  51
  52 ### TYPES #####################################################################
  53
  54 AC_TYPE_UINT8_T
  55 AC_TYPE_UINT16_T
  56 AC_TYPE_INT32_T
  57 AC_TYPE_UINT32_T
  58
  59 ### INTERNATIONALIZATION ######################################################
  60
  61 AM_GNU_GETTEXT_VERSION([0.17])
  62 GETTEXT_PACKAGE=chimara
  63 AC_SUBST(GETTEXT_PACKAGE)
  64 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
  65
  66 ### CHECK FOR LIBRARIES #######################################################
  67
  68 GTK_REQUIRED_VERSION=2.8
  69 GLIB_REQUIRED_VERSION=2.6
  70
  71 AC_SUBST(GTK_REQUIRED_VERSION)
  72 AC_SUBST(GLIB_REQUIRED_VERSION)
  73
  74 # Libraries needed to build Chimara library
  75 PKG_CHECK_MODULES([CHIMARA], [
  76         glib-2.0 >= $GLIB_REQUIRED_VERSION
  77         gtk+-2.0 >= $GTK_REQUIRED_VERSION
  78         gthread-2.0
  79         gmodule-2.0
  80         pango
  81 ])
  82 CHIMARA_LIBS="$CHIMARA_LIBS -lm"
  83 AC_SUBST(CHIMARA_LIBS)
  84 # Libraries needed to build test programs
  85 PKG_CHECK_MODULES([TEST], [
  86         gtk+-2.0 >= $GTK_REQUIRED_VERSION
  87         gmodule-2.0
  88 ])
  89
  90 ### OUTPUT ####################################################################
  91
  92 # Output platform-specific definitions to config.h
  93 AC_CONFIG_HEADERS([config.h])
  94 # List of other files for Autoconf to output
  95 AC_CONFIG_FILES([
  96 Makefile
  97 chimara.pc
  98 chimara-plugin.pc
  99 libchimara/Makefile
 100 interpreters/Makefile
 101 interpreters/frotz/Makefile
 102 interpreters/nitfol/Makefile
 103 interpreters/glulxe/Makefile
 104 interpreters/git/Makefile
 105 tests/Makefile
 106 docs/Makefile
 107 docs/reference/Makefile
 108 docs/reference/version.xml
 109 docs/reference/build-selector-table.pl
 110 po/Makefile.in
 111 ])
 112 # Do it
 113 AC_OUTPUT
 114