configure.ac

   1 # configure.ac with sensible comments
   2
   3 ### INITIALIZATION ############################################################
   4
   5 # Initialize Autoconf
   6 # Args: (human-readable package name, package version, bug report address,
   7 # tarballname)
   8 AC_INIT([chimara], [0.1])
   9 # Sanity check to make sure we are running Autoconf from the right directory
  10 AC_CONFIG_SRCDIR(libchimara/chimara-glk.c)
  11 # Put m4 macros in their own directory
  12 AC_CONFIG_MACRO_DIR(m4)
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([-Wall])
  15 # Configure with --enable-silent-rules to cut down on clutter
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 ### LIBRARY VERSIONING ########################################################
  19 # Only update immediately before a public release
  20
  21 CHIMARA_CURRENT=0  # Increment if interface changes
  22 CHIMARA_REVISION=0 # Increment if source changes; set 0 if interface changes
  23 CHIMARA_AGE=0 # Increment if interfaces added; set 0 if removed
  24 LT_VERSION_INFO="$CHIMARA_CURRENT:$CHIMARA_REVISION:$CHIMARA_AGE"
  25 AC_SUBST(LT_VERSION_INFO)
  26
  27 ### REQUIREMENTS ##############################################################
  28 GTK_REQUIRED_VERSION=2.12
  29 GLIB_REQUIRED_VERSION=2.16
  30 GTK_DOC_REQUIRED_VERSION=1.11
  31 AC_SUBST(GTK_REQUIRED_VERSION)
  32 AC_SUBST(GLIB_REQUIRED_VERSION)
  33 AC_SUBST(GTK_DOC_REQUIRED_VERSION) # Gtk-Doc 1.11 required
  34
  35 ### DECLARE COMPILERS #########################################################
  36
  37 AC_USE_SYSTEM_EXTENSIONS     # Define _GNU_SOURCE if using GCC
  38 AC_PROG_CC                   # C compiler
  39 AM_PROG_CC_C_O               # Automake requires this for per-target CFLAGS
  40 AC_C_INLINE                  # Define inline keyword
  41 AC_PROG_YACC                 # Building nitfol requires yacc
  42
  43 ### DECLARE PROGRAMS ##########################################################
  44
  45 AC_PROG_INSTALL              # Install
  46 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:]) # Disable unnecessary Libtool checks
  47 m4_defun([_LT_AC_LANG_F77_CONFIG], [:]) # to save time (1.5 only)
  48 LT_INIT                      # Libtool 2.2.6 and up
  49 #LT_INIT([dlopen])           # Should call it this way, but
  50 #LT_PREREQ([2.2.6])          # ...goddamn Debian still has 1.5
  51 AC_PROG_LIBTOOL              # Old way of declaring Libtool
  52 AM_GNU_GETTEXT([external])   # Gettext, link to system libintl
  53 IT_PROG_INTLTOOL    # Intltool
  54 PKG_PROG_PKG_CONFIG          # pkg_config
  55 GTK_DOC_CHECK($GTK_DOC_REQUIRED_VERSION)
  56 # Other utilities used in this package's various make scripts
  57 AC_PROG_AWK
  58 AC_PATH_PROG([PERL], [perl]) # Perl
  59 AC_PATH_PROG([TEST], [test]) # Test
  60 AC_PATH_PROG([ECHO], [echo]) # Echo
  61
  62 ### TYPES #####################################################################
  63
  64 AC_TYPE_UINT8_T
  65 AC_TYPE_UINT16_T
  66 AC_TYPE_INT32_T
  67 AC_TYPE_UINT32_T
  68
  69 ### INTERNATIONALIZATION ######################################################
  70
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 GETTEXT_PACKAGE=chimara
  73 AC_SUBST(GETTEXT_PACKAGE)
  74 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
  75
  76 ### ILIAD #####################################################################
  77 AC_ARG_ENABLE([iliad],
  78   [AS_HELP_STRING([--enable-iliad],[Compiles Chimara for the iLiad])],
  79   [AS_CASE([${enableval}],
  80            [yes], [iliad=true],
  81            [no], [iliad=false],
  82            [AC_MSG_ERROR([bad value ${enableval} for --enable-iliad])]
  83    )],
  84    [iliad=false]
  85 )
  86
  87 AM_CONDITIONAL([TARGET_ILIAD], [$TEST "x$iliad" = xtrue])
  88
  89 ### RPM CONFIGURATION ##########################################################
  90 # --enable-rpm requires rpm and rpmbuild
  91 AC_PATH_PROG([RPMBUILD], [rpmbuild], [notfound])
  92 AC_ARG_ENABLE([rpm],
  93         [AS_HELP_STRING([--enable-rpm],[Configure for building RPM package [no] (requires rpm and rpmbuild)])],
  94         [AS_CASE([${enableval}],
  95                 [yes], [AS_IF(
  96                         [$TEST "x$RPMBUILD" = xnotfound],
  97                                 [AC_MSG_ERROR([rpmbuild is required for --enable-rpm])],
  98                         [rpm=true])],
  99                 [no],  [rpm=false],
 100                 [AC_MSG_ERROR([bad value ${enableval} for --enable-rpm])]
 101         )],
 102         [rpm=false]
 103 )
 104 AM_CONDITIONAL([BUILDING_RPM], [$TEST "x$rpm" = xtrue])
 105 # The user can specify the RPM release number in the environment (e.g. '1')
 106 AC_ARG_VAR([RPM_RELEASE], [Release number to build RPMs with [1]])
 107 AS_IF([$TEST "x$RPM_RELEASE" = x], [RPM_RELEASE=1])
 108
 109 ### CHECK FOR LIBRARIES #######################################################
 110
 111 # Libraries needed to build Chimara library
 112 PKG_CHECK_MODULES([CHIMARA], [
 113         glib-2.0 >= $GLIB_REQUIRED_VERSION
 114         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 115         gthread-2.0
 116         gmodule-2.0
 117         pango
 118 ])
 119 CHIMARA_LIBS="$CHIMARA_LIBS -lm"
 120 AC_SUBST(CHIMARA_LIBS)
 121 # Libraries needed to build test programs
 122 PKG_CHECK_MODULES([TEST], [
 123         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 124         gmodule-2.0 >= $GLIB_REQUIRED_VERSION
 125 ])
 126
 127 # Plugin flags; include '-module' in each Makefile.am, because AC_SUBSTed
 128 # variables are black boxes to Automake, so it has to know about it being a
 129 # module in the makefile itself.
 130 PLUGIN_LIBTOOL_FLAGS='-avoid-version -shared -export-symbols-regex "^glk"'
 131 AC_SUBST(PLUGIN_LIBTOOL_FLAGS)
 132
 133 ### OUTPUT ####################################################################
 134
 135 # Output platform-specific definitions to config.h
 136 AC_CONFIG_HEADERS([config.h])
 137 # List of other files for Autoconf to output
 138 AC_CONFIG_FILES([
 139 Makefile
 140 chimara.pc
 141 chimara-plugin.pc
 142 chimara.spec
 143 libchimara/Makefile
 144 interpreters/Makefile
 145 interpreters/frotz/Makefile
 146 interpreters/nitfol/Makefile
 147 interpreters/glulxe/Makefile
 148 interpreters/git/Makefile
 149 tests/Makefile
 150 docs/Makefile
 151 docs/reference/Makefile
 152 docs/reference/version.xml
 153 docs/reference/build-selector-table.pl
 154 po/Makefile.in
 155 ])
 156
 157 # Do it
 158 AC_OUTPUT
 159