configure.ac

   1 # configure.ac with sensible comments
   2
   3 ### INITIALIZATION ############################################################
   4
   5 AC_PREREQ([2.62]) # Oldest version of Autoconf that works with introspection
   6 # Initialize Autoconf
   7 # Args: (human-readable package name, package version, bug report address,
   8 # tarballname)
   9 AC_INIT([chimara], [0.9])
  10 # Sanity check to make sure we are running Autoconf from the right directory
  11 AC_CONFIG_SRCDIR(libchimara/chimara-glk.c)
  12 # Put m4 macros in their own directory
  13 AC_CONFIG_MACRO_DIR([m4])
  14 # Initialize Automake
  15 AM_INIT_AUTOMAKE([-Wall -Wno-portability])
  16 # Configure with --enable-silent-rules to cut down on clutter
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18
  19 ### LIBRARY VERSIONING ########################################################
  20 # Only update immediately before a public release
  21
  22 CHIMARA_CURRENT=0  # Increment if interface changes
  23 CHIMARA_REVISION=0 # Increment if source changes; set 0 if interface changes
  24 CHIMARA_AGE=0 # Increment if interfaces added; set 0 if removed
  25 LT_VERSION_INFO="$CHIMARA_CURRENT:$CHIMARA_REVISION:$CHIMARA_AGE"
  26 AC_SUBST(LT_VERSION_INFO)
  27
  28 ### REQUIREMENTS ##############################################################
  29 # Recommended GTK version: at least 2.12
  30 # Recommended Glib version: at least 2.16
  31 GTK_REQUIRED_VERSION=2.6
  32 GLIB_REQUIRED_VERSION=2.6
  33 GTK_DOC_REQUIRED_VERSION=1.9
  34 AC_SUBST(GTK_REQUIRED_VERSION)
  35 AC_SUBST(GLIB_REQUIRED_VERSION)
  36 AC_SUBST(GTK_DOC_REQUIRED_VERSION)
  37
  38 ### DECLARE COMPILERS #########################################################
  39
  40 AC_USE_SYSTEM_EXTENSIONS     # Define _GNU_SOURCE if using GCC
  41 AC_PROG_CC                   # C compiler
  42 AM_PROG_CC_C_O               # Automake requires this for per-target CFLAGS
  43 AC_C_INLINE                  # Define inline keyword
  44 AC_PROG_YACC                 # Building nitfol requires yacc
  45
  46 ### DECLARE PROGRAMS ##########################################################
  47
  48 AC_PROG_INSTALL              # Install
  49 LT_INIT([dlopen])            # Libtool 2.2.6 and up
  50 LT_PREREQ([2.2.6])
  51 AM_GNU_GETTEXT([external])   # Gettext, link to system libintl
  52 IT_PROG_INTLTOOL([0.40.0])   # Intltool
  53 PKG_PROG_PKG_CONFIG          # pkg_config
  54 GTK_DOC_CHECK($GTK_DOC_REQUIRED_VERSION)
  55 GLIB_GSETTINGS               # GSettings
  56 # Other utilities used in this package's various make scripts
  57 AC_PROG_AWK
  58 AC_PATH_PROG([PERL], [perl]) # Perl
  59 AC_PATH_PROG([TEST], [test]) # Test
  60 AC_PATH_PROG([ECHO], [echo]) # Echo
  61
  62 ### TYPES #####################################################################
  63
  64 AC_TYPE_UINT8_T
  65 AC_TYPE_UINT16_T
  66 AC_TYPE_INT32_T
  67 AC_TYPE_UINT32_T
  68
  69 ### INTERNATIONALIZATION ######################################################
  70
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 GETTEXT_PACKAGE=chimara
  73 AC_SUBST(GETTEXT_PACKAGE)
  74 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
  75
  76 ### INTROSPECTION ##############################################################
  77
  78 GOBJECT_INTROSPECTION_CHECK([0.6.7])
  79
  80 ### ILIAD #####################################################################
  81 AC_ARG_ENABLE([iliad],
  82         [AS_HELP_STRING([--enable-iliad=@<:@yes/no@:>@],
  83                 [Compiles Chimara for the iLiad @<:@default=no@:>@])],
  84         [],
  85         [enable_iliad=no])
  86 AM_CONDITIONAL(TARGET_ILIAD, $TEST "x$enable_iliad" = xyes)
  87
  88 ### BUILD WITHOUT RECENT FILES MANAGER #########################################
  89 # (to work around a bug on OS X)
  90 AC_ARG_ENABLE([recent],
  91         [AS_HELP_STRING([--disable-recent],
  92                 [Omit recent files menu (to work around a bug on OS X])],
  93         [],
  94         [enable_recent=yes])
  95 AS_IF([$TEST "x$enable_recent" = "xyes"],
  96         [OPEN_RECENT_MENU_ITEM="<menuitem action=\"recent\"/>"],
  97         [OPEN_RECENT_MENU_ITEM="<!--  <menuitem action=\"recent\"/>-->"])
  98 AC_SUBST(OPEN_RECENT_MENU_ITEM)
  99
 100 ### RPM CONFIGURATION ##########################################################
 101 # --enable-rpm requires rpm and rpmbuild
 102 AC_PATH_PROG([RPMBUILD], [rpmbuild], [notfound])
 103 AC_ARG_ENABLE([rpm],
 104         [AS_HELP_STRING([--enable-rpm=@<:@yes/no@:>@],
 105                 [Configure for building RPM package @<:@default=no@:>@ (requires rpm and rpmbuild)])],
 106         [AS_IF([$TEST "x$enable_rpm" = xyes],
 107                 [AS_IF([$TEST "x$RPMBUILD" = xnotfound],
 108                         [AC_MSG_ERROR([rpmbuild is required for --enable-rpm])])])],
 109         [enable_rpm=no])
 110 AM_CONDITIONAL(BUILDING_RPM, $TEST "x$enable_rpm" = xyes)
 111
 112 ### SOUND LIBRARY TO USE ######################################################
 113
 114 AC_ARG_WITH([gstreamer],
 115         [AS_HELP_STRING([--without-gstreamer], [Disable GStreamer sound])],
 116         [],
 117         [with_gstreamer=yes])
 118 SOUND_MODULE=
 119 AS_IF([$TEST "x$with_gstreamer" != xno],
 120         [AC_DEFINE([GSTREAMER_SOUND], [1], [Define to enable sound support with GStreamer])
 121         SOUND_MODULE="gstreamer-0.10 >= 0.10.12"])
 122
 123 ### CHECK FOR LIBRARIES #######################################################
 124
 125 # Libraries needed to build Chimara library
 126 PKG_CHECK_MODULES([CHIMARA], [
 127         glib-2.0 >= $GLIB_REQUIRED_VERSION
 128         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 129         gthread-2.0
 130         gmodule-2.0
 131         pango
 132         $SOUND_MODULE
 133 ])
 134 CHIMARA_LIBS="$CHIMARA_LIBS -lm"
 135 AC_SUBST(CHIMARA_LIBS)
 136 # Libraries needed to build test programs
 137 PKG_CHECK_MODULES([TEST], [
 138         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 139         gmodule-2.0 >= $GLIB_REQUIRED_VERSION
 140         libgda-4.0
 141 ])
 142
 143 # GStreamer plugins needed to run library
 144 AS_IF([$TEST "x$with_gstreamer" != xno], [
 145         m4_defun([AX_GST_REQUIRE_ELEMENT],
 146                 [AM_GST_ELEMENT_CHECK([$1],
 147                         [],
 148                         [AC_MSG_ERROR([GStreamer element $1 not found. You need to install gstreamer-plugins-m4_default([$2], [base]).])]
 149                 )]
 150         )
 151         AX_GST_REQUIRE_ELEMENT([giostreamsrc])
 152         AX_GST_REQUIRE_ELEMENT([typefind])
 153         AX_GST_REQUIRE_ELEMENT([audioconvert])
 154         AX_GST_REQUIRE_ELEMENT([volume])
 155         AX_GST_REQUIRE_ELEMENT([oggdemux])
 156         AX_GST_REQUIRE_ELEMENT([vorbisdec])
 157         AX_GST_REQUIRE_ELEMENT([autoaudiosink], [good])
 158         AX_GST_REQUIRE_ELEMENT([aiffparse], [bad])
 159         AX_GST_REQUIRE_ELEMENT([modplug], [bad])
 160 ])
 161
 162 # Plugin flags; include '-module' in each Makefile.am, because AC_SUBSTed
 163 # variables are black boxes to Automake, so it has to know about it being a
 164 # module in the makefile itself.
 165 PLUGIN_LIBTOOL_FLAGS='-avoid-version -shared -export-symbols-regex "^glk"'
 166 AC_SUBST(PLUGIN_LIBTOOL_FLAGS)
 167
 168 ### OUTPUT ####################################################################
 169
 170 # Output platform-specific definitions to config.h
 171 AC_CONFIG_HEADERS([config.h])
 172 # List of other files for Autoconf to output
 173 AC_CONFIG_FILES([
 174 Makefile
 175 chimara.pc
 176 chimara-plugin.pc
 177 chimara.spec
 178 libchimara/Makefile
 179 interpreters/Makefile
 180 interpreters/frotz/Makefile
 181 interpreters/nitfol/Makefile
 182 interpreters/glulxe/Makefile
 183 interpreters/git/Makefile
 184 tests/Makefile
 185 player/Makefile
 186 player/chimara.menus
 187 docs/Makefile
 188 docs/reference/Makefile
 189 docs/reference/version.xml
 190 docs/reference/build-selector-table.pl
 191 po/Makefile.in
 192 babel/Makefile
 193 ])
 194
 195 # Do it
 196 AC_OUTPUT
 197