X-Git-Url: https://git.stderr.nl/gitweb?a=blobdiff_plain;f=configure.ac;h=fa880056a90b0b70c56d91220fc3916eae4c9c56;hb=69bcc9a14851bb6e68b2f79e3b92d00cab3a55d8;hp=d1b91f43bf247aaac3efc5c9cb60f62a1ad6e117;hpb=c6cb6dcf2f5e1c581a847e8619ee49f75b2ec979;p=projects%2Fchimara%2Fchimara.git

diff --git a/configure.ac b/configure.ac
old mode 100755
new mode 100644
index d1b91f4..fa88005
--- a/configure.ac
+++ b/configure.ac
@@ -1,67 +1,100 @@
-dnl Process this file with autoconf to produce a configure script.
-dnl Created by Anjuta application wizard.
+# configure.ac with sensible comments
 
-AC_INIT(chimara, 0.1)
+### INITIALIZATION ############################################################
 
-AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
-AM_CONFIG_HEADER(config.h)
-AM_MAINTAINER_MODE
+# Initialize Autoconf 
+# Args: (human-readable package name, package version, bug report address, 
+# tarballname)
+AC_INIT([chimara], [0.1])
+# Sanity check to make sure we are running Autoconf from the right directory
+AC_CONFIG_SRCDIR(libchimara/chimara-glk.c)
+# Put m4 macros in their own directory
+AC_CONFIG_MACRO_DIR(m4)
+# Initialize Automake
+AM_INIT_AUTOMAKE([-Wall])
+# Configure with --enable-silent-rules to cut down on clutter
+AM_SILENT_RULES
 
-AC_ISC_POSIX
-AC_PROG_CC
-AM_PROG_CC_STDC
-AC_HEADER_STDC
+### LIBRARY VERSIONING ########################################################
+# Only update immediately before a public release
 
-dnl ***************************************************************************
-dnl Internatinalization
-dnl ***************************************************************************
+CHIMARA_CURRENT=0  # Increment if interface changes
+CHIMARA_REVISION=0 # Increment if source changes; set 0 if interface changes
+CHIMARA_AGE=0 # Increment if interfaces added; set 0 if removed
+LT_VERSION_INFO="$CHIMARA_CURRENT:$CHIMARA_REVISION:$CHIMARA_AGE"
+AC_SUBST(LT_VERSION_INFO)
+
+### DECLARE PROGRAMS ##########################################################
+
+AC_PROG_CC                 # C compiler
+AM_PROG_CC_C_O             # Automake requires this for per-target CFLAGS
+AC_PROG_INSTALL            # Install
+m4_defun([_LT_AC_LANG_CXX_CONFIG], [:]) # Disable unnecessary Libtool checks
+m4_defun([_LT_AC_LANG_F77_CONFIG], [:]) # to save time (1.5 only)
+LT_INIT                    # Libtool 2.2.6 and up
+#LT_INIT([dlopen])         # Should call it this way, but
+#LT_PREREQ([2.2.6])        # ...goddamn Debian still has 1.5
+AC_PROG_LIBTOOL            # Old way of declaring Libtool
+AM_GNU_GETTEXT([external]) # Gettext, link to system libintl
+IT_PROG_INTLTOOL([0.35.0]) # Intltool
+PKG_PROG_PKG_CONFIG        # pkg_config
+GTK_DOC_CHECK(1.9)         # Gtk-Doc
+
+### TYPES #####################################################################
+
+AC_TYPE_INT32_T
+AC_TYPE_UINT32_T
+
+### INTERNATIONALIZATION ######################################################
+
+AM_GNU_GETTEXT_VERSION([0.17])
 GETTEXT_PACKAGE=chimara
 AC_SUBST(GETTEXT_PACKAGE)
 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
-AM_GLIB_GNU_GETTEXT
-IT_PROG_INTLTOOL([0.35.0])
 
-dnl AM_PROG_LIBTOOL
+### CHECK FOR LIBRARIES #######################################################
 
-PKG_CHECK_MODULES([CHIMARA], [gtk+-2.0 >= 2.8 gthread-2.0])
-AC_SUBST(CHIMARA_CFLAGS)
+GTK_REQUIRED_VERSION=2.8
+GLIB_REQUIRED_VERSION=2.6
+
+AC_SUBST(GTK_REQUIRED_VERSION)
+AC_SUBST(GLIB_REQUIRED_VERSION)
+
+# Libraries needed to build Chimara library
+PKG_CHECK_MODULES([CHIMARA], [
+	glib-2.0 >= $GLIB_REQUIRED_VERSION
+	gtk+-2.0 >= $GTK_REQUIRED_VERSION
+	gthread-2.0 
+	gmodule-2.0
+	pango
+])
+CHIMARA_LIBS="$CHIMARA_LIBS -lm"
 AC_SUBST(CHIMARA_LIBS)
+# Libraries needed to build test programs
+PKG_CHECK_MODULES([TEST], [
+	gtk+-2.0 >= $GTK_REQUIRED_VERSION 
+	gmodule-2.0
+])
+
+### OUTPUT ####################################################################
 
-##################################################
-# Check for gtk-doc.
-##################################################
-AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
-if test "x$with_html_dir" = "x" ; then
-  HTML_DIR='${datadir}/gtk-doc/html'
-else
-  HTML_DIR=$with_html_dir
-fi
-AC_SUBST(HTML_DIR)
-
-gtk_doc_min_version=1.0
-AC_MSG_CHECKING([gtk-doc version >= $gtk_doc_min_version])
-if pkg-config --atleast-version=$gtk_doc_min_version gtk-doc; then
-  AC_MSG_RESULT(yes)
-  GTKDOC=true
-else
-  AC_MSG_RESULT(no)
-  GTKDOC=false
-fi
-dnl Let people disable the gtk-doc stuff.
-AC_ARG_ENABLE(gtk-doc,
-              [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]],
-	      enable_gtk_doc="$enableval", enable_gtk_doc=auto)
-if test x$enable_gtk_doc = xauto ; then
-  if test x$GTKDOC = xtrue ; then
-    enable_gtk_doc=yes
-  else
-    enable_gtk_doc=no
-  fi
-fi
-AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
-
-AC_OUTPUT([
+# Output platform-specific definitions to config.h
+AC_CONFIG_HEADERS([config.h])
+# List of other files for Autoconf to output
+AC_CONFIG_FILES([
 Makefile
-src/Makefile
+chimara.pc
+chimara-plugin.pc
+libchimara/Makefile
+interpreters/Makefile
+interpreters/frotz/Makefile
+interpreters/nitfol/Makefile
+tests/Makefile
+docs/Makefile
+docs/reference/Makefile
+docs/reference/version.xml
 po/Makefile.in
 ])
+# Do it
+AC_OUTPUT
+