gavinc/uf_xfolk_meta

   1 # Blosxom Plugin: uf_xfolk_meta
   2 # Author(s): Gavin Carr <gavin@openfusion.com.au>
   3 # Version: 0.001000
   4 # Documentation: 'perldoc uf_xfolk_meta'
   5
   6 package uf_xfolk_meta;
   7
   8 use strict;
   9
  10 # Uncomment next line to enable debug output (don't uncomment debug() lines)
  11 #use Blosxom::Debug debug_level => 1;
  12
  13 # --- Configurable variables -----
  14
  15 my %config = ();
  16
  17 # URL to use as base URL for tag links
  18 $config{tagbase} = "$blosxom::url/tags";
  19
  20 # Extra CSS classes to add to the microformat container e.g. to turn display off
  21 $config{class} = '';
  22 #$config{class} = 'nodisplay';
  23
  24 # Whether to automatically add microformat to story bodies. If not set,
  25 # you must explicitly add $uf_adr_meta::adr to a template somewhere.
  26 $config{auto_append_to_body} = 1;
  27
  28 # What markup style to use for your adr, if auto-appending.
  29 # 3 styles are currently defined:
  30 # 'div-span' uses a 'div' elt for the container, and 'span' elements for the fields
  31 # 'ul' uses a 'ul' list for the container, and 'li' elements for the fields
  32 # 'dl' uses a 'dl' list for the container, 'dt' elements for field names, and
  33 #    'dd' elements for the fields themselves
  34 #$config{style} = 'div-span';
  35 #$config{style} = 'ul';
  36 $config{style} = 'dl';
  37
  38 # --------------------------------
  39 # __END_CONFIG__
  40
  41 use vars qw($xfolk);
  42
  43 # Attributes which if set will cause us to skip this plugin (looks like an hcard)
  44 my @skip_attr = qw(fn name);
  45
  46 $config{style} = 'div-span' unless $config{style} eq 'ul' or $config{style} eq 'dl';
  47
  48 sub start { 1 }
  49
  50 # Return the first existing metadata item key and value given a list of keys
  51 sub _get_meta {
  52     for my $attr ( @_ ) {
  53         my $meta_attr = $attr;
  54         $meta_attr =~ s/-/_/g;
  55         my $value = $blosxom::meta{$meta_attr};
  56         $value = eval "\$meta::$attr" unless defined $value;
  57         return wantarray ? ( $attr, $value ) : $value if defined $value;
  58     }
  59     return wantarray ? () : undef;
  60 }
  61
  62 sub story {
  63     my ($pkg, $path, $filename, $story_ref, $title_ref, $body_ref) = @_;
  64
  65     # Skip if any of the @skip_attr are set
  66     for (@skip_attr) {
  67         return 1 if $blosxom::meta{$_} || eval "\$meta::$_";
  68     }
  69
  70     my $story_style = _get_meta( 'xfolk_style' ) || $config{style};
  71     my $ctag = $story_style eq 'div-span' ? 'div' : $story_style;
  72     my $etag = $story_style eq 'div-span' ? 'span' :
  73                $story_style eq 'ul' ? 'li' : 'dd';
  74
  75     # Required metadata
  76     my $url = _get_meta('url', 'taggedlink');
  77     my $title = _get_meta('title');
  78     my $tags = _get_meta('tags');
  79     my $description = _get_meta('description');
  80     return 1 unless defined $url && defined $title;
  81
  82     $xfolk = '';
  83     my $container_classes = 'xfolkentry';
  84     if (my $meta_class = _get_meta('xfolk_class')) {
  85       $container_classes .= " $meta_class";
  86     }
  87     else {
  88       $container_classes .= " $config{class}" if $config{class};
  89     }
  90     $xfolk .= qq(<$ctag class="$container_classes">\n);
  91     $xfolk .= qq(<dt>URL</dt>) if $story_style eq 'dl';
  92     $xfolk .= qq(<$etag class="xfolk_link"><a class="taggedlink" href="$url" title="$title">$title</a></$etag>\n);
  93     if ($tags) {
  94       $xfolk .= qq(<dt>Tags</dt>) if $story_style eq 'dl';
  95       $xfolk .= qq(<$etag class="xfolk_tags">);
  96       my @tags = ();
  97       for (split /\s*,\s*/, $tags) {
  98         push @tags, qq(<a rel="tag" href="$config{tagbase}/$_">$_</a>);
  99       }
 100       $xfolk .= join ', ', @tags if @tags;
 101       $xfolk .= qq(</$etag>\n);
 102     }
 103     if ($description) {
 104       $xfolk .= qq(<dt>Description</dt>) if $story_style eq 'dl';
 105       $xfolk .= qq(<$etag class="description">$description</$etag>\n)
 106     }
 107     $xfolk .= qq(</$ctag>\n);
 108     # debug(1, "uf_xfolk_meta: $xfolk\n");
 109
 110     my $autoappend = _get_meta( 'xfolk_autoappend' );
 111     $autoappend = $config{auto_append_to_body} unless defined $autoappend;
 112     return 1 unless $autoappend;
 113
 114     $$body_ref .= "\n\n$xfolk\n\n";
 115
 116     return 1;
 117 }
 118
 119 1;
 120
 121 __END__
 122
 123 =head1 NAME
 124
 125 uf_xfolk_meta - plugin to create a 'xfolk' (bookmark) microformat tag
 126 from post metadata
 127
 128 =head1 DESCRIPTION
 129
 130 uf_xfolk_meta is a plugin to create an 'xfolk' (bookmark) microformat tag
 131 from metadata in your post. The microformat tag is created in the
 132 $uf_xfolk_meta::xfolk variable for use in templates or by other plugins,
 133 or if the 'auto_append_to_body' config variable is set (it is by default),
 134 uf_xfolk_meta will append the tag to your story body automatically.
 135
 136 =head2 REQUIRED METADATA ITEMS
 137
 138 =over 4
 139
 140 =item url (or taggedlink)
 141
 142 The URL for the bookmarked page.
 143
 144 =item title
 145
 146 The title to use for the bookmarked page.
 147
 148 =back
 149
 150 If any required metadata is missing the plugin just skips the story.
 151
 152 =head2 OPTIONAL METADATA ITEMS
 153
 154 =over 4
 155
 156 =item tags
 157
 158 Comma-separated list of tags applying to the bookmarked page.
 159
 160 =item description
 161
 162 Description or summary of the bookmarked page.
 163
 164 =back
 165
 166 =head2 Config Elements
 167
 168 uf_xfolk_meta also supports a couple of config elements that can be used to
 169 override plugin config data on a per-story basis:
 170
 171 =over 4
 172
 173 =item XFolk-Class (metamail) / xfolk_class (meta)
 174
 175 This class (or list of classes) is appended to the class list applied to the
 176 top-level xfolk element in the rendered xfolk i.e. it overrides the
 177 'class' config variable.
 178
 179 =item XFolk-Autoappend (metamail) / xfolk_autoappend (meta)
 180
 181 This is a flag (0 or 1) indicating whether the rendered xfolk should be
 182 automatically appended to the story body. It overrides the 'auto_append_to_body'
 183 config variable.
 184
 185 =item XFolk-Style (metamail) / xfolk_style (meta)
 186
 187 One of the following styles: 'div-span', 'ul', 'dl', used to render the xfolk.
 188 It overrides the 'style' config variable.
 189
 190 =back
 191
 192 =head1 USAGE
 193
 194 uf_xfolk_meta should be loaded after the meta plugins (meta
 195 itself, or the metaclear/metamail/metadir/metafile family).
 196
 197 =head1 SEE ALSO
 198
 199 Microformats.org: http://www.microformats.org/, http://microformats.org/wiki/xfolk.
 200
 201 Blosxom: http://blosxom.sourceforge.net/
 202
 203 =head1 AUTHOR
 204
 205 Gavin Carr <gavin@openfusion.com.au>, http://www.openfusion.net/
 206
 207 =head1 LICENSE
 208
 209 Copyright 2007, Gavin Carr.
 210
 211 This plugin is licensed under the same terms as blosxom itself i.e.
 212
 213 Permission is hereby granted, free of charge, to any person obtaining a
 214 copy of this software and associated documentation files (the "Software"),
 215 to deal in the Software without restriction, including without limitation
 216 the rights to use, copy, modify, merge, publish, distribute, sublicense,
 217 and/or sell copies of the Software, and to permit persons to whom the
 218 Software is furnished to do so, subject to the following conditions:
 219
 220 The above copyright notice and this permission notice shall be included
 221 in all copies or substantial portions of the Software.
 222
 223 THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 224 IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 225 FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
 226 THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR
 227 OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
 228 ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
 229 OTHER DEALINGS IN THE SOFTWARE.
 230
 231 =cut
 232
 233 # vim:ft=perl