gavinc/uf_geo_meta

   1 # Blosxom Plugin: uf_geo_meta
   2 # Author(s): Gavin Carr <gavin@openfusion.com.au>
   3 # Version: 0.001000
   4 # Documentation: 'perldoc uf_geo_meta'
   5
   6 package uf_geo_meta;
   7
   8 use strict;
   9
  10 # Uncomment next line to enable debug output (don't uncomment debug() lines)
  11 #use Blosxom::Debug debug_level => 1;
  12
  13 # --- Configurable variables -----
  14
  15 my %config = ();
  16
  17 # Extra CSS classes to add to the microformat container e.g. to turn display off
  18 $config{class} = '';
  19 #$config{class} = 'nodisplay';
  20
  21 # Whether to automatically add microformat to story bodies. If not set,
  22 # you must explicitly add $uf_adr_meta::adr to a template somewhere.
  23 $config{auto_append_to_body} = 1;
  24
  25 # What markup style to use for your adr, if auto-appending.
  26 # 3 styles are currently defined:
  27 # 'div-span' uses a 'div' elt for the container, and 'span' elements for the fields
  28 # 'ul' uses a 'ul' list for the container, and 'li' elements for the fields
  29 # 'dl' uses a 'dl' list for the container, 'dt' elements for field names, and
  30 #    'dd' elements for the fields themselves
  31 #$config{style} = 'div-span';
  32 #$config{style} = 'ul';
  33 $config{style} = 'dl';
  34
  35 # --------------------------------
  36 # __END_CONFIG__
  37
  38 use vars qw($geo);
  39
  40 # Attributes which if set will cause us to skip this plugin (looks like an adr)
  41 my @skip_attr = qw(locality region postal-code country-name city state postcode country);
  42
  43 $config{style} = 'div-span' unless $config{style} eq 'ul' or $config{style} eq 'dl';
  44
  45 sub start { 1 }
  46
  47 # Return the first existing metadata item key and value given a list of keys
  48 sub _get_meta {
  49     for my $attr ( @_ ) {
  50         my $meta_attr = $attr;
  51         $meta_attr =~ s/-/_/g;
  52         my $value = $blosxom::meta{$meta_attr};
  53         $value = eval "\$meta::$attr" unless defined $value;
  54         return wantarray ? ( $attr, $value ) : $value if defined $value;
  55     }
  56     return wantarray ? () : undef;
  57 }
  58
  59 sub story {
  60     my ($pkg, $path, $filename, $story_ref, $title_ref, $body_ref) = @_;
  61
  62     # Skip if any of the @skip_attr are set
  63     for (@skip_attr) {
  64         return 1 if $blosxom::meta{$_} || eval "\$meta::$_";
  65     }
  66
  67     my $story_style = _get_meta( 'geo_style' ) || $config{style};
  68     my $ctag = $story_style eq 'div-span' ? 'div' : $story_style;
  69     my $etag = $story_style eq 'div-span' ? 'span' :
  70                $story_style eq 'ul' ? 'li' : 'dd';
  71     my $sep = ', ' if $story_style eq 'div-span';
  72
  73     my $latitude = _get_meta('latitude');
  74     my $longitude = _get_meta('longitude');
  75     return 1 unless defined $latitude && defined $longitude;
  76
  77     $geo = '';
  78     my $container_classes = 'geo';
  79     if (my $meta_class = _get_meta('geo_class')) {
  80       $container_classes .= " $meta_class";
  81     }
  82     else {
  83       $container_classes .= " $config{class}" if $config{class};
  84     }
  85
  86     $geo .= qq(<$ctag class="$container_classes">);
  87     $geo .= qq(<dt>Latitude</dt>) if $story_style eq 'dl';
  88     $geo .= qq(<$etag class="latitude">$latitude</$etag>);
  89     $geo .= $sep if $story_style = 'div-span';
  90     $geo .= qq(<dt>Longitude</dt>) if $story_style eq 'dl';
  91     $geo .= qq(<$etag class="longitude">$longitude</$etag>);
  92     $geo .= qq(</$ctag>);
  93     # debug(1, "uf_geo_meta: $geo\n");
  94
  95     my $autoappend = _get_meta( 'geo_autoappend' );
  96     $autoappend = $config{auto_append_to_body} unless defined $autoappend;
  97     return 1 unless $autoappend;
  98
  99     $$body_ref .= "\n\n$geo\n\n";
 100
 101     return 1;
 102 }
 103
 104 1;
 105
 106 __END__
 107
 108 =head1 NAME
 109
 110 uf_geo_meta - plugin to create a 'geo' microformat tag from post metadata
 111
 112 =head1 DESCRIPTION
 113
 114 uf_geo_meta is a plugin to create a 'geo' microformat tag from metadata
 115 in your post. The microformat tag is created in the $uf_geo_meta::geo
 116 variable for use in templates or by other plugins, or if the
 117 'auto_append_to_body' config variable is set (it is by default), uf_geo_meta
 118 will append the tag to your story body automatically.
 119
 120 =head2 REQUIRED METADATA ITEMS
 121
 122 =over 4
 123
 124 =item latitude
 125
 126 A decimal between -90.0 (South Pole) and +90.0 (North Pole), indicating
 127 degrees of latitude.
 128
 129 =item longitude
 130
 131 A decimal between -180.0 (western hemisphere) and +180.0 (eastern hemisphere),
 132 indicating degrees of longitude.
 133
 134 =back
 135
 136 If any required metadata is missing the plugin just skips the story.
 137
 138 =head2 Config Elements
 139
 140 uf_geo_meta also supports a couple of config elements that can be used to
 141 override plugin config data on a per-story basis:
 142
 143 =over 4
 144
 145 =item Geo-Class (metamail) / geo_class (meta)
 146
 147 This class (or list of classes) is appended to the class list applied to the
 148 top-level geo element in the rendered geo i.e. it overrides the
 149 'class' config variable.
 150
 151 =item Geo-Autoappend (metamail) / geo_autoappend (meta)
 152
 153 This is a flag (0 or 1) indicating whether the rendered geo should be
 154 automatically appended to the story body. It overrides the 'auto_append_to_body'
 155 config variable.
 156
 157 =item Geo-Style (metamail) / geo_style (meta)
 158
 159 One of the following styles: 'div-span', 'ul', 'dl', used to render the geo.
 160 It overrides the 'style' config variable.
 161
 162 =back
 163
 164 =head1 EXAMPLE
 165
 166 Adding a geo microformat to  your post then becomes as simple as:
 167
 168   Testing uf_geo_meta
 169   Latitude: -33.717770
 170   Longitude: 151.115886
 171
 172 if using metamail, or:
 173
 174   Random blog post
 175   meta-latitude: -33.717770
 176   meta-longitude: 151.115886
 177
 178 =head1 USAGE
 179
 180 uf_geo_meta should be loaded after the meta plugins (meta
 181 itself, or the metaclear/metamail/metadir/metafile family).
 182
 183 =head1 SEE ALSO
 184
 185 Microformats.org: http://www.microformats.org/,
 186 http://microformats.org/wiki/geo.
 187
 188 Blosxom: http://blosxom.sourceforge.net/
 189
 190 =head1 AUTHOR
 191
 192 Gavin Carr <gavin@openfusion.com.au>, http://www.openfusion.net/
 193
 194 =head1 LICENSE
 195
 196 Copyright 2007, Gavin Carr.
 197
 198 This plugin is licensed under the same terms as blosxom itself i.e.
 199
 200 Permission is hereby granted, free of charge, to any person obtaining a
 201 copy of this software and associated documentation files (the "Software"),
 202 to deal in the Software without restriction, including without limitation
 203 the rights to use, copy, modify, merge, publish, distribute, sublicense,
 204 and/or sell copies of the Software, and to permit persons to whom the
 205 Software is furnished to do so, subject to the following conditions:
 206
 207 The above copyright notice and this permission notice shall be included
 208 in all copies or substantial portions of the Software.
 209
 210 THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 211 IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 212 FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
 213 THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR
 214 OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
 215 ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
 216 OTHER DEALINGS IN THE SOFTWARE.
 217
 218 =cut
 219
 220 # vim:ft=perl