configure.ac

   1 # configure.ac with sensible comments
   2
   3 ### INITIALIZATION ############################################################
   4
   5 AC_PREREQ([2.62]) # Oldest version of Autoconf that works with introspection
   6 # Initialize Autoconf
   7 # Args: (human-readable package name, package version, bug report address,
   8 # tarballname)
   9 AC_INIT([chimara], [0.9])
  10 # Sanity check to make sure we are running Autoconf from the right directory
  11 AC_CONFIG_SRCDIR(libchimara/chimara-glk.c)
  12 # Put m4 macros in their own directory
  13 AC_CONFIG_MACRO_DIR([m4])
  14 # Initialize Automake
  15 AM_INIT_AUTOMAKE([-Wall -Wno-portability])
  16 # Configure with --enable-silent-rules to cut down on clutter
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18
  19 ### LIBRARY VERSIONING ########################################################
  20 # Only update immediately before a public release
  21
  22 CHIMARA_CURRENT=0  # Increment if interface changes
  23 CHIMARA_REVISION=0 # Increment if source changes; set 0 if interface changes
  24 CHIMARA_AGE=0 # Increment if interfaces added; set 0 if removed
  25 LT_VERSION_INFO="$CHIMARA_CURRENT:$CHIMARA_REVISION:$CHIMARA_AGE"
  26 AC_SUBST(LT_VERSION_INFO)
  27
  28 ### REQUIREMENTS ##############################################################
  29 # Recommended GTK version: at least 2.12
  30 # Recommended Glib version: at least 2.16
  31 GTK_REQUIRED_VERSION=2.6
  32 GLIB_REQUIRED_VERSION=2.6
  33 GTK_DOC_REQUIRED_VERSION=1.12
  34 AC_SUBST(GTK_REQUIRED_VERSION)
  35 AC_SUBST(GLIB_REQUIRED_VERSION)
  36 AC_SUBST(GTK_DOC_REQUIRED_VERSION)
  37
  38 ### DECLARE COMPILERS #########################################################
  39
  40 AC_USE_SYSTEM_EXTENSIONS     # Define _GNU_SOURCE if using GCC
  41 AC_PROG_CC                   # C compiler
  42 AM_PROG_CC_C_O               # Automake requires this for per-target CFLAGS
  43 AC_C_INLINE                  # Define inline keyword
  44 AC_PROG_YACC                 # Building nitfol requires yacc
  45
  46 ### DECLARE PROGRAMS ##########################################################
  47
  48 AC_PROG_INSTALL              # Install
  49 LT_INIT([dlopen])            # Libtool 2.2.6 and up
  50 LT_PREREQ([2.2.6])
  51 AM_GNU_GETTEXT([external])   # Gettext, link to system libintl
  52 IT_PROG_INTLTOOL([0.40.0])   # Intltool
  53 PKG_PROG_PKG_CONFIG          # pkg_config
  54 GTK_DOC_CHECK($GTK_DOC_REQUIRED_VERSION)
  55 GLIB_GSETTINGS               # GSettings
  56 # Other utilities used in this package's various make scripts
  57 AC_PROG_AWK
  58 AC_PATH_PROG([PERL], [perl]) # Perl
  59 AC_PATH_PROG([TEST], [test]) # Test
  60 AC_PATH_PROG([ECHO], [echo]) # Echo
  61
  62 ### TYPES #####################################################################
  63
  64 AC_TYPE_UINT8_T
  65 AC_TYPE_UINT16_T
  66 AC_TYPE_INT32_T
  67 AC_TYPE_UINT32_T
  68
  69 ### INTERNATIONALIZATION ######################################################
  70
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 GETTEXT_PACKAGE=chimara
  73 AC_SUBST(GETTEXT_PACKAGE)
  74 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
  75
  76 ### INTROSPECTION ##############################################################
  77
  78 GOBJECT_INTROSPECTION_CHECK([0.6.7])
  79
  80 ### RPM CONFIGURATION ##########################################################
  81 # --enable-rpm requires rpm and rpmbuild
  82 AC_PATH_PROG([RPMBUILD], [rpmbuild], [notfound])
  83 AC_ARG_ENABLE([rpm],
  84         [AS_HELP_STRING([--enable-rpm=@<:@yes/no@:>@],
  85                 [Configure for building RPM package @<:@default=no@:>@ (requires rpm and rpmbuild)])],
  86         [AS_IF([$TEST "x$enable_rpm" = xyes],
  87                 [AS_IF([$TEST "x$RPMBUILD" = xnotfound],
  88                         [AC_MSG_ERROR([rpmbuild is required for --enable-rpm])])])],
  89         [enable_rpm=no])
  90 AM_CONDITIONAL(BUILDING_RPM, $TEST "x$enable_rpm" = xyes)
  91
  92 ### SOUND LIBRARY TO USE ######################################################
  93
  94 AC_ARG_WITH([gstreamer],
  95         [AS_HELP_STRING([--without-gstreamer], [Disable GStreamer sound])],
  96         [],
  97         [with_gstreamer=yes])
  98 SOUND_MODULE=
  99 AS_IF([$TEST "x$with_gstreamer" != xno],
 100         [AC_DEFINE([GSTREAMER_SOUND], [1], [Define to enable sound support with GStreamer])
 101         SOUND_MODULE="gstreamer-0.10 >= 0.10.12"])
 102
 103 ### WHETHER TO GENERATE A .VAPI FILE ##########################################
 104 # Requires vapigen
 105 AC_PATH_PROG([VAPIGEN], [vapigen], [notfound])
 106 AM_CONDITIONAL(BUILDING_VAPI, $TEST "x$VAPIGEN" != xnotfound)
 107
 108 ### CHECK FOR LIBRARIES #######################################################
 109
 110 # Libraries needed to build Chimara library
 111 PKG_CHECK_MODULES([CHIMARA], [
 112         glib-2.0 >= $GLIB_REQUIRED_VERSION
 113         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 114         gthread-2.0
 115         gmodule-2.0
 116         pango
 117         $SOUND_MODULE
 118 ])
 119 CHIMARA_LIBS="$CHIMARA_LIBS -lm"
 120 AC_SUBST(CHIMARA_LIBS)
 121 # Libraries needed to build Chimara player
 122 PKG_CHECK_MODULES([PLAYER], [
 123         glib-2.0 >= $GLIB_REQUIRED_VERSION
 124         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 125         gmodule-2.0
 126 ])
 127 # Libraries needed to build test programs
 128 PKG_CHECK_MODULES([TEST], [
 129         gtk+-2.0 >= $GTK_REQUIRED_VERSION
 130         gmodule-2.0 >= $GLIB_REQUIRED_VERSION
 131 ])
 132
 133 # GStreamer plugins needed to run library
 134 AS_IF([$TEST "x$with_gstreamer" != xno], [
 135         m4_defun([AX_GST_REQUIRE_ELEMENT],
 136                 [AM_GST_ELEMENT_CHECK([$1],
 137                         [],
 138                         [AC_MSG_ERROR([GStreamer element $1 not found. You need to install gstreamer-plugins-m4_default([$2], [base]).])]
 139                 )]
 140         )
 141         AX_GST_REQUIRE_ELEMENT([giostreamsrc])
 142         AX_GST_REQUIRE_ELEMENT([typefind])
 143         AX_GST_REQUIRE_ELEMENT([audioconvert])
 144         AX_GST_REQUIRE_ELEMENT([volume])
 145         AX_GST_REQUIRE_ELEMENT([oggdemux])
 146         AX_GST_REQUIRE_ELEMENT([vorbisdec])
 147         AX_GST_REQUIRE_ELEMENT([autoaudiosink], [good])
 148         AX_GST_REQUIRE_ELEMENT([aiffparse], [bad])
 149         AX_GST_REQUIRE_ELEMENT([modplug], [bad])
 150 ])
 151
 152 # Plugin flags; include '-module' in each Makefile.am, because AC_SUBSTed
 153 # variables are black boxes to Automake, so it has to know about it being a
 154 # module in the makefile itself.
 155 PLUGIN_LIBTOOL_FLAGS='-avoid-version -shared -export-symbols-regex "^glk"'
 156 AC_SUBST(PLUGIN_LIBTOOL_FLAGS)
 157
 158 ### OUTPUT ####################################################################
 159
 160 # Output platform-specific definitions to config.h
 161 AC_CONFIG_HEADERS([config.h])
 162 # List of other files for Autoconf to output
 163 AC_CONFIG_FILES([
 164 Makefile
 165 chimara.pc
 166 chimara-plugin.pc
 167 chimara.spec
 168 libchimara/Makefile
 169 interpreters/Makefile
 170 interpreters/frotz/Makefile
 171 interpreters/nitfol/Makefile
 172 interpreters/glulxe/Makefile
 173 interpreters/git/Makefile
 174 tests/Makefile
 175 player/Makefile
 176 player/config.py
 177 docs/Makefile
 178 docs/reference/Makefile
 179 docs/reference/version.xml
 180 docs/reference/build-selector-table.pl
 181 po/Makefile.in
 182 ])
 183
 184 # Do it
 185 AC_OUTPUT
 186