configure.ac

   1 # configure.ac with sensible comments
   2
   3 ### INITIALIZATION ############################################################
   4
   5 AC_PREREQ([2.62]) # Oldest version of Autoconf that works with introspection
   6 # Initialize Autoconf
   7 # Args: (human-readable package name, package version, bug report address,
   8 # tarballname)
   9 AC_INIT([chimara], [0.9])
  10 # Sanity check to make sure we are running Autoconf from the right directory
  11 AC_CONFIG_SRCDIR(libchimara/chimara-glk.c)
  12 # Put m4 macros in their own directory
  13 AC_CONFIG_MACRO_DIR([m4])
  14 # Initialize Automake
  15 AM_INIT_AUTOMAKE([-Wall -Wno-portability])
  16 # Configure with --enable-silent-rules to cut down on clutter
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18
  19 ### LIBRARY VERSIONING ########################################################
  20 # Only update immediately before a public release
  21
  22 CHIMARA_CURRENT=0  # Increment if interface changes
  23 CHIMARA_REVISION=0 # Increment if source changes; set 0 if interface changes
  24 CHIMARA_AGE=0 # Increment if interfaces added; set 0 if removed
  25 LT_VERSION_INFO="$CHIMARA_CURRENT:$CHIMARA_REVISION:$CHIMARA_AGE"
  26 AC_SUBST(LT_VERSION_INFO)
  27
  28 ### REQUIREMENTS ##############################################################
  29 GTK_REQUIRED_VERSION=3.2
  30 GLIB_REQUIRED_VERSION=2.16
  31 GTK_DOC_REQUIRED_VERSION=1.12
  32 AC_SUBST(GTK_REQUIRED_VERSION)
  33 AC_SUBST(GLIB_REQUIRED_VERSION)
  34 AC_SUBST(GTK_DOC_REQUIRED_VERSION)
  35
  36 ### DECLARE COMPILERS #########################################################
  37
  38 AC_USE_SYSTEM_EXTENSIONS     # Define _GNU_SOURCE if using GCC
  39 AC_PROG_CC                   # C compiler
  40 AM_PROG_CC_C_O               # Automake requires this for per-target CFLAGS
  41 AC_C_INLINE                  # Define inline keyword
  42 AC_PROG_YACC                 # Building nitfol requires yacc
  43
  44 ### DECLARE PROGRAMS ##########################################################
  45
  46 AC_PROG_INSTALL              # Install
  47 LT_INIT([dlopen])            # Libtool 2.2.6 and up
  48 LT_PREREQ([2.2.6])
  49 AM_GNU_GETTEXT([external])   # Gettext, link to system libintl
  50 IT_PROG_INTLTOOL([0.40.0])   # Intltool
  51 PKG_PROG_PKG_CONFIG          # pkg_config
  52 GTK_DOC_CHECK($GTK_DOC_REQUIRED_VERSION)
  53 GLIB_GSETTINGS               # GSettings
  54 # Other utilities used in this package's various make scripts
  55 AC_PROG_AWK
  56 AC_PATH_PROG([PERL], [perl]) # Perl
  57 AC_PATH_PROG([TEST], [test]) # Test
  58 AC_PATH_PROG([ECHO], [echo]) # Echo
  59
  60 ### TYPES #####################################################################
  61
  62 AC_TYPE_UINT8_T
  63 AC_TYPE_UINT16_T
  64 AC_TYPE_INT32_T
  65 AC_TYPE_UINT32_T
  66
  67 ### INTERNATIONALIZATION ######################################################
  68
  69 AM_GNU_GETTEXT_VERSION([0.17])
  70 GETTEXT_PACKAGE=chimara
  71 AC_SUBST(GETTEXT_PACKAGE)
  72 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
  73
  74 ### INTROSPECTION ##############################################################
  75
  76 GOBJECT_INTROSPECTION_CHECK([0.6.7])
  77
  78 ### RPM CONFIGURATION ##########################################################
  79 # --enable-rpm requires rpm and rpmbuild
  80 AC_PATH_PROG([RPMBUILD], [rpmbuild], [notfound])
  81 AC_ARG_ENABLE([rpm],
  82         [AS_HELP_STRING([--enable-rpm=@<:@yes/no@:>@],
  83                 [Configure for building RPM package @<:@default=no@:>@ (requires rpm and rpmbuild)])],
  84         [AS_IF([$TEST "x$enable_rpm" = xyes],
  85                 [AS_IF([$TEST "x$RPMBUILD" = xnotfound],
  86                         [AC_MSG_ERROR([rpmbuild is required for --enable-rpm])])])],
  87         [enable_rpm=no])
  88 AM_CONDITIONAL(BUILDING_RPM, $TEST "x$enable_rpm" = xyes)
  89
  90 ### SOUND LIBRARY TO USE ######################################################
  91
  92 AC_ARG_WITH([gstreamer],
  93         [AS_HELP_STRING([--without-gstreamer], [Disable GStreamer sound])],
  94         [],
  95         [with_gstreamer=yes])
  96 SOUND_MODULE=
  97 AS_IF([$TEST "x$with_gstreamer" != xno],
  98         [AC_DEFINE([GSTREAMER_SOUND], [1], [Define to enable sound support with GStreamer])
  99         SOUND_MODULE="gstreamer-0.10 >= 0.10.12"])
 100
 101 ### WHETHER TO GENERATE A .VAPI FILE ##########################################
 102 # Requires vapigen
 103 AC_PATH_PROG([VAPIGEN], [vapigen], [notfound])
 104 AM_CONDITIONAL(BUILDING_VAPI, $TEST "x$VAPIGEN" != xnotfound)
 105
 106 ### CHECK FOR LIBRARIES #######################################################
 107
 108 # Libraries needed to build Chimara library
 109 PKG_CHECK_MODULES([CHIMARA], [
 110         glib-2.0 >= $GLIB_REQUIRED_VERSION
 111         gtk+-3.0 >= $GTK_REQUIRED_VERSION
 112         gthread-2.0
 113         gmodule-2.0
 114         pango
 115         $SOUND_MODULE
 116 ])
 117 CHIMARA_LIBS="$CHIMARA_LIBS -lm"
 118 AC_SUBST(CHIMARA_LIBS)
 119 # Libraries needed to build Chimara player
 120 PKG_CHECK_MODULES([PLAYER], [
 121         glib-2.0 >= $GLIB_REQUIRED_VERSION
 122         gtk+-3.0 >= $GTK_REQUIRED_VERSION
 123         gmodule-2.0
 124 ])
 125 # Libraries needed to build interpreter plugins
 126 PKG_CHECK_MODULES([PLUGIN], [
 127         glib-2.0  dnl Any version will do
 128         gtk+-3.0
 129         libpeas-1.0
 130         libpeas-gtk-1.0
 131 ])
 132 # Libraries needed to build test programs
 133 PKG_CHECK_MODULES([TEST], [
 134         gtk+-3.0 >= $GTK_REQUIRED_VERSION
 135         gmodule-2.0 >= $GLIB_REQUIRED_VERSION
 136 ])
 137
 138 # GStreamer plugins needed to run library
 139 AS_IF([$TEST "x$with_gstreamer" != xno], [
 140         m4_defun([AX_GST_REQUIRE_ELEMENT],
 141                 [AM_GST_ELEMENT_CHECK([$1],
 142                         [],
 143                         [AC_MSG_ERROR([GStreamer element $1 not found. You need to install gstreamer-plugins-m4_default([$2], [base]).])]
 144                 )]
 145         )
 146         AX_GST_REQUIRE_ELEMENT([giostreamsrc])
 147         AX_GST_REQUIRE_ELEMENT([typefind])
 148         AX_GST_REQUIRE_ELEMENT([audioconvert])
 149         AX_GST_REQUIRE_ELEMENT([volume])
 150         AX_GST_REQUIRE_ELEMENT([oggdemux])
 151         AX_GST_REQUIRE_ELEMENT([vorbisdec])
 152         AX_GST_REQUIRE_ELEMENT([autoaudiosink], [good])
 153         AX_GST_REQUIRE_ELEMENT([aiffparse], [bad])
 154         AX_GST_REQUIRE_ELEMENT([modplug], [bad])
 155 ])
 156
 157 # Plugin flags; include '-module' in each Makefile.am, because AC_SUBSTed
 158 # variables are black boxes to Automake, so it has to know about it being a
 159 # module in the makefile itself.
 160 PLUGIN_LIBTOOL_FLAGS='-avoid-version -shared -export-symbols-regex "(^glk|peas_register_types)"'
 161 AC_SUBST(PLUGIN_LIBTOOL_FLAGS)
 162
 163 ### OUTPUT ####################################################################
 164
 165 # Output platform-specific definitions to config.h
 166 AC_CONFIG_HEADERS([config.h])
 167 # List of other files for Autoconf to output
 168 AC_CONFIG_FILES([
 169 Makefile
 170 chimara.pc
 171 chimara-plugin.pc
 172 chimara.spec
 173 libchimara/Makefile
 174 interpreters/Makefile
 175 tests/Makefile
 176 player/Makefile
 177 player/config.py
 178 docs/Makefile
 179 docs/reference/Makefile
 180 docs/reference/version.xml
 181 docs/reference/build-selector-table.pl
 182 po/Makefile.in
 183 ])
 184
 185 # Do it
 186 AC_OUTPUT
 187